1.2.2 Gemiddeld aantal ingezette fte personeel niet in loondienst (PNIL) met een zorgfunctie.

Concepten

• Gewerkte periode
• Inhuurovereenkomst
• Uitzendovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.2.2
2# Parameters:
3# Ontologie: versie 3.0
4# Het gemiddeld aantal ingezette FTE personeel niet in loondienst (PNIL) met een zorgfunctie in de meetperiode 1 januari t/m 31 december.
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11
12SELECT
13    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Teller)
14    ("Niet van toepassing" AS ?Noemer)
15    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Indicator_FTE36)
16{
17    SELECT 
18        ?maand
19        (SUM(?inzet_uren)/141 AS ?inzet_fte)
20    {
21        BIND("2024-01-01"^^xsd:date AS ?start_periode)
22        BIND("2024-12-31"^^xsd:date AS ?eind_periode)
23
24        VALUES ?type_overeenkomst 
25        { 
26            onz-pers:InhuurOvereenkomst
27            onz-pers:UitzendOvereenkomst
28        }
29        ?overeenkomst 
30            a ?type_overeenkomst ; # personeel niet in loondienst
31            onz-pers:heeftOpdrachtnemer ?persoon ;
32            onz-g:hasPart ?overeenkomst_afspraak .
33        ?overeenkomst_afspraak
34            a onz-pers:WerkOvereenkomstAfspraak ;
35            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
36            onz-g:startDatum ?start_afspraak .
37        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
38        FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
39
40        ?inzet
41            a onz-pers:GewerktePeriode ;
42            onz-g:definedBy ?overeenkomst ;
43            onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
44            onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
45        BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
46        FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
47        FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
48        BIND(MONTH(?start_inzet) AS ?maand)
49    }
50    GROUP BY ?maand
51}